|
Windows 中的Ctrl+C 和Ctrl+V 大家應(yīng)該很熟悉了， 但是您知道剪帖板里有啥？ 舉個(gè)例子， 在 IE4中選一段東東，按Ctrl+C， 然后在FrontPage 中按Ctrl+V， 您選的東東完整地拷貝到了FrontPage 中， 字體， 顏色等等。 明顯， 剪帖板中一定包含了Html 信息， 而如果我們?cè)诰幊桃惨玫竭@些信息， 該怎么辦呢？
本文提供了兩種技巧， 一是如何得到關(guān)于剪貼格式的名稱(chēng)， 一是如何用文本格式顯示剪貼版中特定剪貼格式內(nèi)容。
在我們的第一個(gè)演示中， 利用一個(gè)很笨的方法來(lái)得到 Html 剪貼格式的名稱(chēng)。 GetClipboardFormatName 可以由剪貼板的ID 得到該格式的名稱(chēng)， 于是用一個(gè)循環(huán)來(lái)查找所有包含Html 文字的格式。
在第二個(gè)例子中， 我們使用了在例子一中得到的名稱(chēng)， 把在 IE4 中剪貼的Html 內(nèi)容合并到一個(gè) TextBox 中， 好讓我們知道里面有什么樣的信息。
實(shí)現(xiàn)步驟
例子一 得到剪貼格式的名稱(chēng)
1 新建一個(gè)工程。
2 在工程中增加一個(gè)命令按鈕(Command1)。
3 增加下面的代碼：
Private Declare Function GetClipboardFormatName Lib "user32" Alias "GetClipboardFormatNameA" (ByVal wFormat As Long, ByVal lpString As String, ByVal nMaxCount As Long) As Long
Private Sub Command1_Click()
Dim FormatID As Long
Dim BufferLen As Long
Dim Buffer As String * 80
For FormatID = 50000 To 60000 '一般有效的 ID 在該區(qū)內(nèi)
BufferLen = GetClipboardFormatName(FormatID, Buffer, 80)
If BufferLen > 0 Then
If InStr(UCase(Left(Buffer, BufferLen)), "HTML") > 0 Then MsgBox FormatID & ":" & Buffer
End If
Next
End Sub
4 運(yùn)行該程序， 可以發(fā)現(xiàn)多個(gè)帶 Html 的格式名稱(chēng)， 經(jīng)過(guò)測(cè)試，HTML Format是我們要找的。 注意： 沒(méi)有 IE4 的話， 可以使用 RTF 進(jìn)行查詢， 以查看 RichText 的剪貼內(nèi)容。
例子二 得到 IE4 的剪貼內(nèi)容
1 新建一個(gè)工程。
2 在工程中增加一個(gè)命令按鈕(Command1)， 一個(gè)TextBox(Text1)， 允許多行顯示。
3 增加下面的代碼：
Private Declare Function OpenClipboard Lib "USER32" (ByVal hWnd As Long) As Long
Private Declare Function CloseClipboard Lib "USER32" () As Long
Private Declare Function GetClipboardData Lib "USER32" (ByVal wFormat As Long) As Long
Private Declare Function IsClipboardFormatAvailable Lib "USER32" (ByVal wFormat As Long) As Long
Private Declare Function RegisterClipboardFormat Lib "USER32" Alias "RegisterClipboardFormatA" (ByVal lpString As String) As Long
Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalSize Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (lpvDest As Any, lpvSource As Any, ByVal cbCopy As Long)
Public Function GetClipboardIDForCustomFormat(ByVal sName As String) As Long
Dim wFormat As Long
wFormat = RegisterClipboardFormat(sName & Chr$(0))
If (wFormat > &HC000&) Then
GetClipboardIDForCustomFormat = wFormat
End If
End Function
Public Function GetClipboardDataAsString(ByVal hWndOwner As Long, ByVal lFormatID As Long) As String
Dim bData() As Byte
Dim hMem As Long
Dim lSize As Long
Dim lPtr As Long
If (OpenClipboard(hWndOwner)) Then
If (IsClipboardFormatAvailable(lFormatID) <> 0) Then
hMem = GetClipboardData(lFormatID)
If (hMem <> 0) Then
lSize = GlobalSize(hMem)
If (lSize > 0) Then
lPtr = GlobalLock(hMem)
If (lPtr <> 0) Then
ReDim bData(0 To lSize - 1) As Byte
CopyMemory bData(0), ByVal lPtr, lSize
GlobalUnlock hMem
GetClipboardDataAsString = StrConv(bData, vbUnicode)
End If
End If
End If
End If
CloseClipboard
End If
End Function
Private Sub Command1_Click()
Dim lID As Long
Dim sText As String
' 如果沒(méi)有 IE4，可以使用 "RTF Format"
lID = GetClipboardIDForCustomFormat("HTML Format")
If (lID <> 0) Then
sText = GetClipboardDataAsString(Me.hWnd, lID)
Text1.Text = sText
End If
End Sub
4 運(yùn)行該程序。 在IE4 中選任意的東東， 按Ctrl+C， 然后按 Command1， 可以在Text1 中看到如下的內(nèi)容， 漢字顯示問(wèn)題與 GetClipboardDataAsString = StrConv(bData, vbUnicode) 有關(guān)：
Version:1.0
StartHTML:000000213
EndHTML:000000863
StartFragment:000000758
EndFragment:000000772
StartSelection:000000758
EndSelection:000000772
SourceURL:file://G:\FrontPage Webs\Content\vbtt\download.htm
<!DOCTYPE HTML PUBLIC "-//W3C//DTD W3 HTML//EN">
|
溫馨提示：喜歡本站的話，請(qǐng)收藏一下本站！
